xor: Wasm-Textanweisung

Probieren Sie es aus

(module

  (func (export "xor") (param $a i32) (param $b i32) (result i32)
    ;; load both numbers onto the stack
    local.get $a
    local.get $b

    ;; `xor` both numbers and return the result
    i32.xor
  )

)

const url = "{%wasm-url%}";
await WebAssembly.instantiateStreaming(fetch(url), { console }).then(
  (result) => {
    const xor = result.instance.exports.xor;

    const res = xor(0b10000010, 0b01101111);
    console.log(numToBin(res));
    // Expected output: "11101101"
  },
);

function numToBin(num) {
  return (num >>> 0).toString(2).padStart(8, "0");
}

Syntax

value_type.xor

value_type

Der Typ des Wertes, auf dem die Anweisung ausgeführt wird. Die folgenden Typen unterstützen xor:

• i32
• i64
• v128

xor

Die xor-Anweisung. Muss immer nach dem value_type und einem Punkt (.) angegeben werden.

Typ

[input1, input2] -> [output]

input1

Der erste Eingabewert.

input2

Der zweite Eingabewert.

output

Der Ausgabewert.

Bei einem Nicht-SIMD-xor handelt es sich um grundlegende numerische Werte wie 14 oder 3.

Bei einem SIMD-xor handelt es sich um v128-Werteinterpretationen, zum Beispiel i32x4 9 4 -16 100. Jede Spur des Ergebnisses, das auf den Stapel geschoben wird, ist das bitweise XOR der entsprechenden Spuren in den Eingabewerten.

Binärcodierung

Beispiele

SIMD-xor-Beispiel

In diesem Beispiel demonstrieren wir, wie v128.xor auf zwei SIMD-Werte angewendet wird und einen der Spurwerte des Ergebnisses ausgibt.

JavaScript

In unserem Skript holen wir eine Referenz zu einem <p>-Element, in das wir unser Ergebnis ausgeben werden. Dann definieren wir ein Objekt, das in Wasm importiert wird und eine einzelne Funktion enthält, die einen Wert in das Ausgabe-<p> schreibt. Wir kompilieren und instanziieren unser Wasm-Modul mit der Methode WebAssembly.instantiateStreaming() und importieren dabei das Objekt.

<p></p>

const outputElem = document.querySelector("p");

const obj = {
  output(val) {
    outputElem.textContent += val;
  },
};

WebAssembly.instantiateStreaming(fetch("{%wasm-url%}"), {
  obj,
});

Wasm

In unserem Wasm-Modul importieren wir zuerst die JavaScript-Funktion output() und stellen sicher, dass sie einen i32-Parameter hat. Dann deklarieren wir zwei SIMD-i32x4-Werte und verwenden v128.xor, um die Bits der binären Darstellung jedes Wertes zu "xor"-en. Schließlich extrahieren wir den in Spur 3 gespeicherten Wert des Ausgabewertes mit der extract_lane-Anweisung und geben ihn durch den Aufruf der importierten Funktion output() an das DOM aus.

(module
  ;; Import output function
  (import "obj" "output" (func $output (param i32)))

  (func $main
    ;; load two SIMD values onto the stack
    v128.const i32x4 12 10 11 782
    v128.const i32x4 12 14 15 400

    v128.xor ;; "xor" the two values
    i32x4.extract_lane 3 ;; Extract a value from the result
    call $output
  )

  (start $main)
)

Ergebnis

Die Ausgabe lautet wie folgt:

670 wird ausgegeben, da dies das Ergebnis der "xor"-Operation von Spur 3 des ersten Wertes (782) und des zweiten Wertes (400) ist. Wenn Sie ihre binären Äquivalente betrachten, wird klar, wie dies funktioniert:

782 = 0000 0011 0000 1110
400 = 0000 0001 1001 0000
      -------------------
XOR = 0000 0010 1001 1110 = 670